# Copyright (c) 2023-present The Limenka developers
# Distributed under the MIT software license, see the accompanying
# file COPYING or https://opensource.org/license/mit/.

add_library(limenka_crypto STATIC EXCLUDE_FROM_ALL
  aes.cpp
  bignum.cpp
  bulletproofs.cpp
  chacha20.cpp
  chacha20poly1305.cpp
  hex_base.cpp
  hkdf_sha256_32.cpp
  hmac_sha256.cpp
  hmac_sha512.cpp
  muhash.cpp
  poly1305.cpp
  ripemd160.cpp
  sha1.cpp
  sha256.cpp
  sha256_sse4.cpp
  sha3.cpp
  sha512.cpp
  siphash.cpp
  ../support/cleanse.cpp
)

target_link_libraries(limenka_crypto
  PRIVATE
    core_interface
)

if(HAVE_SSE41)
  target_compile_definitions(limenka_crypto PRIVATE ENABLE_SSE41)
  target_sources(limenka_crypto PRIVATE sha256_sse41.cpp)
  set_property(SOURCE sha256_sse41.cpp PROPERTY
    COMPILE_OPTIONS ${SSE41_CXXFLAGS}
  )
endif()

if(HAVE_AVX2)
  target_compile_definitions(limenka_crypto PRIVATE ENABLE_AVX2)
  target_sources(limenka_crypto PRIVATE sha256_avx2.cpp)
  set_property(SOURCE sha256_avx2.cpp PROPERTY
    COMPILE_OPTIONS ${AVX2_CXXFLAGS}
  )
endif()

if(HAVE_SSE41 AND HAVE_X86_SHANI)
  target_compile_definitions(limenka_crypto PRIVATE ENABLE_SSE41 ENABLE_X86_SHANI)
  target_sources(limenka_crypto PRIVATE sha256_x86_shani.cpp)
  set_property(SOURCE sha256_x86_shani.cpp PROPERTY
    COMPILE_OPTIONS ${SSE41_CXXFLAGS} ${X86_SHANI_CXXFLAGS}
  )
endif()

if(HAVE_ARM_SHANI)
  target_compile_definitions(limenka_crypto PRIVATE ENABLE_ARM_SHANI)
  target_sources(limenka_crypto PRIVATE sha256_arm_shani.cpp)
  set_property(SOURCE sha256_arm_shani.cpp PROPERTY
    COMPILE_OPTIONS ${ARM_SHANI_CXXFLAGS}
  )
endif()

if(ENABLE_POWER8)
  target_compile_definitions(limenka_crypto PRIVATE
    ENABLE_POWER8
    $<IF:$<STREQUAL:${CMAKE_CXX_BYTE_ORDER},BIG_ENDIAN>,WORDS_BIGENDIAN,>
  )
  target_sources(limenka_crypto PRIVATE sha256_power8.cpp)
  set_property(SOURCE sha256_power8.cpp PROPERTY
    COMPILE_OPTIONS ${POWER8_CXXFLAGS}
  )
endif()